StackOverflow2013

Note that there are some explanatory texts on larger screens.

plurals

PO
primarykey
Id
9059509
data
AcceptedAnswerId
0
AnswerCount
0
ClosedDate
CommentCount
0
CommunityOwnedDate
CreationDate
2012-01-30T04:54:01.640
FavoriteCount
0
LastActivityDate
2012-01-30T04:54:01.640
LastEditDate
LastEditorUserId
0
OwnerUserId
699632
ParentId
9056745
PostTypeId
2
Score
0
ViewCount
0
LastEditorDisplayName
text
Body
Let's have a look at writing a document class. Step 1: Declaring the package - package represents where relative to the .fla your document class is stored. If your document class is in the same directory as the .fla, you'll just need to write: <pre><code>package </code></pre> If it's in a folder, you'll need to add that after <code>package</code>. Let's say your document class was in a directory called <code>src</code>: <pre><code>package src </code></pre> Now that that's sorted, you should have something like this: <pre><code>package { // } </code></pre> The next thing you need to do is import the classes that you'll need to use in your document class. You'll want to extend <code>MovieClip</code> in your document class, so lets import that: <pre><code>package { import flash.display.MovieClip; } </code></pre> That's all we'll need to cover your example, so now we move onto the third element required, the class declaration. In this case, it is made up of three parts: <ol> <li>The class namespace - can be either <code>internal</code> (if you only want your class to be accessible from classes in the same package) or <code>public</code> (accessible anywhere in the project).</li> <li>Your class name.</li> <li>What your class will extend - in this case, MovieClip.</li> </ol> All together, yours will look like this: <pre><code>public class Document extends MovieClip </code></pre> Now you'll have something like the below, which means you can start adding <code>properties</code> and <code>methods</code>: <pre><code>package { import flash.display.MovieClip; public class Document extends MovieClip { // } } </code></pre> The first thing you'll want to do is create a <code>constructor</code> for your class. The constructor is called when an instance of this class is created, or in your case being a document class, immediately. Constructors are defined by creating a method with the same name as its containing class. Constructors must also be <code>public</code> and return nothing. Here's your new code with an empty constructor: <pre><code>package { import flash.display.MovieClip; public class Document extends MovieClip { // Constructor public function Document() { // } } } </code></pre> Next step is to create your properties that will belong to your class. In your example you used <code>strGlobal:String</code>, so let's add that. Properties generally belong immediately below the class declaration and above the constructor. Properties are made up of four parts: <ol> <li>Namespace - this determines the accessibility of your property. If you omit this, the default will be <code>internal</code>. For now, these are the basics: <ul> <li><code>public</code> - Your property is accessible from anywhere that have reference to an instance of your class.</li> <li><code>private</code> - Your property is only accessible from within the class - this seems useless at first, but eventually you'll find yourself primarily using this.</li> <li><code>protected</code> - Your property is accessible in classes that extend your class.</li> <li><code>internal</code> - Your property is accessible from classes that are in the same package.</li> </ul></li> <li>Your property name.</li> <li>Your property type.</li> <li>Your property value.</li> </ol> In your case, <code>strGlobal</code> will look something like this: <pre><code>public var strGlobal:String = "Global"; </code></pre> Let's add that to your document class: <pre><code>package { import flash.display.MovieClip; public class Document extends MovieClip { // Properties public var strGlobal:String = "Global"; // Constructor public function Document() { // } } } </code></pre> Next up, you'll want to create your method <code>scopeTest()</code> as per your question. Methods are made up of 5 parts: <ol> <li>Namespace - methods use the same namespaces as properties (see above).</li> <li>Method name.</li> <li>Method arguments.</li> <li>Return type.</li> <li>Content.</li> </ol> <code>scopeTest()</code> doesn't have any arguments and doesn't return anything, so it's going to look like this: <pre><code>public function scopeTest():void { trace(strGlobal); } </code></pre> Methods generally belong anywhere below your constructor, so let's slot it in now: <pre><code>package { import flash.display.MovieClip; public class Document extends MovieClip { // Properties public var strGlobal:String = "Global"; // Constructor public function Document() { // } // Output the value of strGlobal public function scopeTest():void { trace(strGlobal); } } } </code></pre> Now that everything is ready, you'll be able to call <code>scopeTest()</code> from within your constructor. Because the constructor is called immediately, you should see <code>Global</code> printed in your output panel (assuming you've linked to it within the Flash IDE correctly). Hope this helps.
Tags
Title
singulars
PostAcceptedAnswerId
1. This table or related slice is empty.
PostParentId
1. POFlash cs5 code location confusion
 singulars
 PostTypePostTypeId
 PTQuestion
PostTypePostTypeId
1. PTAnswer
UserLastEditorUserId
1. This table or related slice is empty.
UserOwnerUserId
1. USMarty
plurals
PostLinksPostIdRelatedPostId
1. This table or related slice is empty.
PostLinksRelatedPostIdPostId
1. This table or related slice is empty.
PostsAcceptedAnswerId
1. This table or related slice is empty.
PostsParentIdCreationDate
1. This table or related slice is empty.
VotesPostIdCreationDate
1. This table or related slice is empty.
CommentsPostId
1. This table or related slice is empty.

Querying!

Guidance

A row detail

Detail views are divided into sections. All the information in the data section comes from columns in the selected row. The other sections display data from other, related rows.

Related data can be related in a to-one or a to-many fashion. Captions of data related in a to-many fashion link to a list view showing a filtered view of the table.

Try moving around until you find a non-empty to-many entry and click on the label to get to one. You can move back to the root by clicking on the database name in the header.