Databases
StackOverflow2013
Postsdbo
PO
 

Note that there are some explanatory texts on larger screens.

plurals
  1. PO
    primarykey
    data
    text
    <p>Actually, the ValueQ function is not innocent, since it leaks evaluation for code with side effects. Examples:</p> <pre><code>ClearAll[f, g]; f[x_] := Print[x]; g[x_][0] := Print[x]; {ValueQ[f[1]],ValueQ[g[2][0]]} </code></pre> <p>If you remove the ReadProtected Attribute of ValueQ and look at the code, you will see why - the code is very simplistic and does a decent job for OwnValues only. Here is a more complex version which I developed to avoid this problem (you can test that, at least for the examples above, it does not leak evaluation):</p> <pre><code>ClearAll[symbolicHead]; SetAttributes[symbolicHead, HoldAllComplete]; symbolicHead[f_Symbol[___]] := f; symbolicHead[f_[___]] := symbolicHead[f]; symbolicHead[f_] := Head[Unevaluated[f]]; ClearAll[partialEval]; SetAttributes[partialEval, HoldAllComplete]; partialEval[a_Symbol] /; OwnValues[a] =!= {} := Unevaluated[partialEval[a]] /. OwnValues[a]; partialEval[a : f_Symbol[___]] /; DownValues[f] =!= {} := With[{dv = DownValues[f]}, With[{eval = Hold[partialEval[a]] /. dv}, ReleaseHold[eval] /; (First[Extract[eval, {{1, 1}}, HoldComplete]] =!= HoldComplete[a])]]; partialEval[a_] := With[{sub = SubValues[Evaluate[symbolicHead[a]]]}, With[{eval = Hold[partialEval[a]] /. sub}, ReleaseHold[eval] /; (First[Extract[eval, {{1, 1}}, HoldComplete]] =!= HoldComplete[a])]]; ClearAll[valueQ]; SetAttributes[valueQ, HoldAllComplete]; valueQ[expr_] := partialEval[expr] =!= Unevaluated[partialEval[expr]]; </code></pre> <p>This is not complete either, since it does not account for UpValues, NValues, and FormatValues, but this seems to be enough for your stated needs, and also, rules for these three extra cases can perhaps also be added along the same lines as above. </p>
    singulars
    1. This table or related slice is empty.
    1. POChecking if a symbol is defined
      singulars
      1. PTQuestion
    1. PTAnswer
    1. This table or related slice is empty.
    1. USLeonid Shifrin
    plurals
    1. This table or related slice is empty.
    1. This table or related slice is empty.
    1. This table or related slice is empty.
    1. This table or related slice is empty.
    1. VO
      singulars
      1. PO
      1. This table or related slice is empty.
      1. VTUpMod
    2. VO
      singulars
      1. PO
      1. This table or related slice is empty.
      1. VTUpMod
    3. VO
      singulars
      1. PO
      1. This table or related slice is empty.
      1. VTUpMod
    1. COI think ValueQ works for me because I'm using f[] and f[][] as a dictionary to store constants, but I'll keep this recipe in mind if more general need comes up, thanks
      singulars
      1. PO
      1. USYaroslav Bulatov
 

Querying!

 
Guidance
A row detail

Detail views are divided into sections. All the information in the data section comes from columns in the selected row. The other sections display data from other, related rows.

Related data can be related in a to-one or a to-many fashion. Captions of data related in a to-many fashion link to a list view showing a filtered view of the table.

Try moving around until you find a non-empty to-many entry and click on the label to get to one. You can move back to the root by clicking on the database name in the header.

SQuiL has stopped working due to an internal error.

If you are curious you may find further information in the browser console, which is accessible through the devtools (F12).

Reload